Projektowanie Układów ASIC

Laboratorium

 

 

 

Ćwiczenie nr 1. Badanie wzmacniacza operacyjnego CMOS.

1. Wstęp.

            Wzmacniacze operacyjne są bardzo szeroko stosowanymi blokami systemów analogowych jak również i cyfrowych. W niniejszym ćwiczeniu badane są wybrane parametry napięciowego wzmacniacza operacyjnego CMOS zaprojektowanego w nowoczesnej technologii CMOS nwell 0.18um. Celem ćwiczenia jest opanowanie umiejętności zaawansowanych badań symulacyjnych wzmacniaczy operacyjnych. Po wykonaniu przewidzianych czynności należy podać wnioski końcowe a także zaproponować możliwe modyfikacje wzmacniacza, zapewniające poprawę jego parametrów.

2. Przygotowanie do laboratorium.

            Przed przystąpieniem do wykonania ćwiczenia należy odświeżyć wiadomości dotyczące budowy i działania wzmacniaczy operacyjnych jak również należy zapoznać się z obsługą symulatora PSPICE. Na końcu niniejszego opracowania podana jest niezbędna literatura.

3. Wzmacniacz operacyjny.

            Schemat badanego wzmacniacza przedstawiony jest na rys. 1. Lista połączeń łącznie z parametrami modeli do programu SPICE umieszczona jest w załączniku A. Nazwy węzłów oznaczone są kursywą. Wzmacniacz zasilany jest z niesymetrycznego źródła napięciowego o wydajności 3.3V. Poziom masy sygnałowej należy ustalić na równy 1.5V.

Rys. 1. Schemat badanego wzmacniacza operacyjnego CMOS.

4. Instrukcja wykonania ćwiczenia.

            W ramach ćwiczenia należy wykonać badania symulacyjne wzmacniacza wg zamieszczonej poniżej listy. Wyniki symulacji jak również wyniki wykonania pozostałych poleceń należy umieścić w protokole, którego wzór znajduje się w załączniku B. Załącznik ten, po wypełnieniu, należy przesłać pocztą elektroniczną na adres wskazany przez prowadzącego zajęcia.

5. Lista czynności do wykonania w ramach ćwiczenia (jeśli nie wymagano inaczej wszelkie parametry należy wyznaczyć dla V(out) @1.5V):

A)    Należy wyznaczyć (symulacja PSPICE) wejściowe napięcie niezrównoważenia i jeśli nie podano tego inaczej wszystkie inne symulacje należy przeprowadzać przy założeniu podania na wejście napięcia stałego równego napięciu niezrównoważenia.

B)     Opisz krótko (max. 10 zdań) wzmacniacz przedstawiony na rys. 1. Wykonaj analizę stałoprądową i podaj ile wynoszą prądy stałe polaryzujące kolejne stopnie wzmacniające.

C)    Należy wyznaczyć (symulacja PSPICE) wzmocnienie napięciowe w otwartej pętli sprzężenia zwrotnego.

D)    Należy wyznaczyć (symulacja PSPICE) współczynnik CMRR.

E)     Należy wyznaczyć (symulacja PSPICE) współczynniki PSRR.

F)     Należy wyznaczyć (symulacja PSPICE) zniekształcenia nieliniowe dla sygnału wejściowego o amplitudzie 0.5V i częstotliwości 10kHz przy konfiguracji wzmacniacza jako wtórnik napięciowy i przy obciążeniu rezystancją 10k (do masy sygnałowej).

G)    Należy sprawdzić czy wzmacniacz jest wewnętrznie skompensowany i wyznaczyć (symulacja PSPICE) zapas fazy i amplitudy tej kompensacji oraz częstotliwość bieguna dominującego.

H)    Należy założyć, że tranzystory MOS mają 0.5% rozrzuty napięcia progowego oraz współczynnika transkonduktancji (należy dodać lub sprawdzić opcję DEV łącznie z odpowiednią wartością przy parametrach VTH0 oraz TOX w modelach tranzystorów MOS). Następnie należy wykonać 100 krotną analizę Monte Carlo (w skrócie MC) i wyznaczyć zakres zmian wzmocnienia napięciowego w otwartej pętli (zapewniając kompensację wejściowego napięcia niezrównoważenia tj., dla V(out)@1.5V).

I)       Należy wykonać analizę MC jw. ale zbadać zakres występujących wartości wejściowego napięcia niezrównoważenia.

J)       Należy wykonać analizę MC jw. ale zbadać zakres uzyskiwanych wartości współczynnika CMRR.

K)    Należy podać wnioski końcowe (skomentować uzyskane wyniki oraz zaproponować możliwe modyfikacje wzmacniacza) i uwagi co do zakresu ćwiczenia.

 

 

 

Literatura

[1]       Z. Staszak., J. Glinianowicz, D. Czarnecki, skrypt pt. „Układy elektroniczne liniowe”.

[2]       A. Guziński, „Liniowe elektroniczne układy analogowe”, WNT 1992.

[3]       J. Izydorczyk, „PSpice komputerowa symulacja układów elektronicznych”, Helion, 1993.

[4]       B. Pankiewicz, materiały pomocnicze do przedmiotu „ Projektowanie Układów ASIC”, Gdańsk 2005.

 

Dodatek A – lista połączeń badanego wzmacniacza operacyjnego.

PROJEKTOWANIE UKLADOW ASIC Cw nr 1: "Wzmacniacz operacyjny CMOS".

* Zasilanie

Vdd vdd 0 3.3V

 

* Sygnal wejsciowy - napiecie wejsciowe zbalansowane wokol masy analogowej na poziomie 1.5V

Vid in_p in_m 0 ac 1 sin (0 1 10k)

Vcm cm 0 1.5V

E1  in_p cm in_p in_m 0.5

 

* WO

M1   1 in_m 3 0   nfet   W=1.44u  L=0.54u

M2   2 in_p 3 0   nfet   W=1.44u  L=0.54u

M3   1 1 vdd vdd  pfet   W=1.62u  L=0.54u

M4   2 1 vdd vdd  pfet   W=1.62u  L=0.54u

M5   4 2 vdd vdd  pfet   W=48.6u  L=1.62u

M6   4 4 5 0      nfet   W=0.54u  L=0.9u

M7   5 6 0 0      nfet   W=64.8u  L=3.24u

M8   vdd 4 out 0  nfet   W=64.8u  L=1.08u

M9   0 5 out vdd  pfet   W=194.4u L=1.08u

M10  6 6 vdd vdd  pfet   W=0.54u  L=7.2u

M11  6 6 0 0      nfet   W=2.16u  L=1.08u

M12  3 6 0 0      nfet   W=2.16u  L=1.08u

Cc   out 2 0.1p

 

* Analizy - tu nalezy podac niezbedne do wykonania analizy PSPICE

*.dc Vid -10mV 10mV 100uV

*.ac dec 5 1k 10k

*opcjonalne obciazenie

*Rl out cm 10k

*.tran 1u 1m 0.9m

*.four 10k v(rl) v(vid)

*.mc 100 dc v(rl) Ymax output all

*.mc 100 ac v(rl) Ymax output all

 

* Modele

* T49P SPICE BSIM3 VERSION 3.1 PARAMETERS

*SPICE 3f5 Level 8, Star-HSPICE Level 49, UTMOST Level 8

* DATE: Dec  1/04

* LOT: T49P                  WAF: 3011

* Temperature_parameters=Default

.MODEL nfet NMOS (                                LEVEL   = 7

+VERSION = 3.1            TNOM    = 27             TOX     = 4.1E-9 dev=0.5%

+XJ      = 1E-7           NCH     = 2.3549E17      VTH0    = 0.3631313 dev=0.5%

+K1      = 0.5920712      K2      = 3.261973E-3    K3      = 1E-3

+K3B     = 2.9061018      W0      = 1E-7           NLX     = 1.840449E-7

+DVT0W   = 0              DVT1W   = 0              DVT2W   = 0

+DVT0    = 1.4767146      DVT1    = 0.4177419      DVT2    = 8.829889E-3

+U0      = 255.1380803    UA      = -1.597788E-9   UB      = 2.53505E-18

+UC      = 4.766568E-11   VSAT    = 1.010331E5     A0      = 1.80776

+AGS     = 0.3951935      B0      = 2.536033E-7    B1      = 5E-6

+KETA    = -5.061981E-3   A1      = 5.396345E-4    A2      = 0.8936768

+RDSW    = 111.58989      PRWG    = 0.5            PRWB    = -0.2

+WR      = 1              WINT    = 0              LINT    = 1.840173E-8

+XL      = 0              XW      = -1E-8          DWG     = -5.605289E-9

+DWB     = 1.137609E-8    VOFF    = -0.0871468     NFACTOR = 2.3018187

+CIT     = 0              CDSC    = 2.4E-4         CDSCD   = 0

+CDSCB   = 0              ETA0    = 3.127659E-3    ETAB    = 9.485027E-6

+DSUB    = 0.018202       PCLM    = 0.7464953      PDIBLC1 = 0.2263045

+PDIBLC2 = 2.358517E-3    PDIBLCB = -0.1           DROUT   = 0.8266278

+PSCBE1  = 4.915846E10    PSCBE2  = 2.831646E-9    PVAG    = 0.010936

+DELTA   = 0.01           RSH     = 6.6            MOBMOD  = 1

+PRT     = 0              UTE     = -1.5           KT1     = -0.11

+KT1L    = 0              KT2     = 0.022          UA1     = 4.31E-9

+UB1     = -7.61E-18      UC1     = -5.6E-11       AT      = 3.3E4

+WL      = 0              WLN     = 1              WW      = 0

+WWN     = 1              WWL     = 0              LL      = 0

+LLN     = 1              LW      = 0              LWN     = 1

+LWL     = 0              CAPMOD  = 2              XPART   = 0.5

+CGDO    = 8.4E-10        CGSO    = 8.4E-10        CGBO    = 1E-12

+CJ      = 9.619152E-4    PB      = 0.8            MJ      = 0.3787773

+CJSW    = 2.61908E-10    PBSW    = 0.8            MJSW    = 0.157929

+CJSWG   = 3.3E-10        PBSWG   = 0.8            MJSWG   = 0.157929

+CF      = 0              PVTH0   = -6.300783E-5   PRDSW   = -2.1729835

+PK2     = 9.978988E-4    WKETA   = 8.888859E-5    LKETA   = -6.31897E-3

+PU0     = 4.3665601      PUA     = 9.428511E-14   PUB     = 0

+PVSAT   = 1.356405E3     PETA0   = 1.003159E-4    PKETA   = -1.583628E-3    )

*

.MODEL pfet PMOS (                                LEVEL   = 7

+VERSION = 3.1            TNOM    = 27             TOX     = 4.1E-9 dev=0.5%

+XJ      = 1E-7           NCH     = 4.1589E17      VTH0    = -0.3706453 dev=0.5%

+K1      = 0.5740728      K2      = 0.0277093      K3      = 0

+K3B     = 7.9502396      W0      = 1E-6           NLX     = 1.195464E-7

+DVT0W   = 0              DVT1W   = 0              DVT2W   = 0

+DVT0    = 0.6525814      DVT1    = 0.2558611      DVT2    = 0.1

+U0      = 103.6542095    UA      = 1.044279E-9    UB      = 1E-21

+UC      = -1E-10         VSAT    = 1.528072E5     A0      = 1.6482476

+AGS     = 0.3296056      B0      = 3.334823E-7    B1      = 1.106095E-6

+KETA    = 0.0261026      A1      = 0.5575286      A2      = 0.4098665

+RDSW    = 304.2182406    PRWG    = 0.5            PRWB    = 0.5

+WR      = 1              WINT    = 0              LINT    = 3.397866E-8

+XL      = 0              XW      = -1E-8          DWG     = -2.581645E-8

+DWB     = 4.944839E-9    VOFF    = -0.0842496     NFACTOR = 1.9148145

+CIT     = 0              CDSC    = 2.4E-4         CDSCD   = 0

+CDSCB   = 0              ETA0    = 0.0744062      ETAB    = -0.056221

+DSUB    = 0.77235        PCLM    = 2.099528       PDIBLC1 = 8.859692E-4

+PDIBLC2 = 0.021643       PDIBLCB = -1E-3          DROUT   = 0

+PSCBE1  = 3.210588E9     PSCBE2  = 9.291482E-10   PVAG    = 14.895735

+DELTA   = 0.01           RSH     = 7.5            MOBMOD  = 1

+PRT     = 0              UTE     = -1.5           KT1     = -0.11

+KT1L    = 0              KT2     = 0.022          UA1     = 4.31E-9

+UB1     = -7.61E-18      UC1     = -5.6E-11       AT      = 3.3E4

+WL      = 0              WLN     = 1              WW      = 0

+WWN     = 1              WWL     = 0              LL      = 0

+LLN     = 1              LW      = 0              LWN     = 1

+LWL     = 0              CAPMOD  = 2              XPART   = 0.5

+CGDO    = 6.45E-10       CGSO    = 6.45E-10       CGBO    = 1E-12

+CJ      = 1.148706E-3    PB      = 0.8422946      MJ      = 0.408913

+CJSW    = 2.18625E-10    PBSW    = 0.8            MJSW    = 0.3448738

+CJSWG   = 4.22E-10       PBSWG   = 0.8            MJSWG   = 0.3448738

+CF      = 0              PVTH0   = 1.374126E-3    PRDSW   = 0.9646861

+PK2     = 1.205583E-3    WKETA   = 0.0277979      LKETA   = 2.778855E-3

+PU0     = -0.656906      PUA     = -3.48783E-11   PUB     = 1E-21

+PVSAT   = -50.1579558    PETA0   = 1.003159E-4    PKETA   = -3.130573E-3    )

*

.probe

.options trtol=1e-1 itl4=100

.end

 

Dodatek B – wzór protokołu. Zawartość umieszczoną poniżej należy skopiować do osobnego dokumentu i po wypełnieniu wysłać na adres wskazany przez prowadzącego zajęcia.

 

Ćwiczenie nr 1. Badanie wzmacniacza operacyjnego CMOS.

 

Lp.

Nazwa

Wartość

1

Data wykonania ćwiczenia.

 

2

Osoby wykonujące ćwiczenie.

 

3

A. Wejściowe napięcie niezrównoważenia.

 

4

B. Krótki opis układu badanego wzmacniacza (liczba stopni, ich prądy polaryzujące, konfiguracje pracy i inne).

 

5

C. Wzmocnienie napięciowe z otwartą pętlą sprzężenia zwrotnego.

 

6

D. CMRR.

 

7

E. PSRR.

 

8

F. THD.

 

9

G. Zapas fazy i amplitudy oraz częstotliwość bieguna dominującego.

 

10

H. MC – zakres wzmocnienia w otwartej pętli.

 

11

I. MC – zakres wejściowych napięć niezrównoważenia.

 

12

J. MC – zakres CMRR.

 

13

K. Wnioski końcowe i sugestie co do treści ćwiczenia. (maks. 15 zdań)